RabbitFarm

2025-06-08

The Weekly Challenge 324 (Prolog Solutions)

The examples used here are from the weekly challenge problem statement and demonstrate the working solution.

Part 1: 2D Array

You are given an array of integers and two integers $r and $c. Write a script to create two dimension array having $r rows and $c columns using the given array.

Our solution is short and will be contained in a single file that has the following structure.

"ch-1.p" 1≡


⟨create two dimensional array 2 ⟩
◇

We’ll use a straightforward recursive approach.

⟨create two dimensional array 2 ⟩≡


create_array(_, 0, _, []).
create_array(L, Rows, Columns, [Row|T]) :-
create_row(L, Columns, Row, L1),
R is Rows - 1,
create_array(L1, R, Columns, T).

create_row(L, 0, [], L).
create_row([H|T], Columns, [H|Row], L) :-
C is Columns - 1,
create_row(T, C, Row, L).
◇

Fragment referenced in 1.

Sample Run
$ gprolog --consult-file prolog/ch-1.p 
| ?- create_array([1, 2, 3, 4], 2, 2, TwoDArray). 
 
TwoDArray = [[1,2],[3,4]] ? 
 
yes 
| ?- create_array([1, 2, 3], 1, 3, TwoDArray). 
 
TwoDArray = [[1,2,3]] ? 
 
yes 
| ?- create_array([1, 2, 3, 4], 4, 1, TwoDArray). 
 
TwoDArray = [[1],[2],[3],[4]] ? 
 
yes 
| ?-

Part 2: Total XOR

You are given an array of integers. Write a script to return the sum of total XOR for every subset of given array.

GNU Prolog has a sublist/2 predicate which will generate all needed subsets on backtracking. We’ll use this inside of a findall/3. The code required is fairly small, although we’ll define a couple of small utility predicates.

"ch-2.p" 3≡


⟨subtotal 6 ⟩
⟨compute total xor 4 ⟩
⟨combine xors 5 ⟩
◇

⟨compute total xor 4 ⟩≡


total_xor(L, Total):-
findall(S, (
sublist(S, L),
\+ S = []
), SubLists),
maplist(combine, SubLists, Combined),
maplist(subtotal, Combined, SubTotals),
sum_list(SubTotals, Total).
◇

Fragment referenced in 3.

⟨combine xors 5 ⟩≡


combine([], 0).
combine([H|T], Combined):-
combine(T, Combined1),
Combined = xor(H, Combined1).
◇

Fragment referenced in 3.

⟨subtotal 6 ⟩≡


subtotal(Combined, X):-
X is Combined.
◇

Fragment referenced in 3.

Sample Run
$ gprolog --consult-file prolog/ch-2.p 
| ?- total_xor([1, 3], Total). 
 
Total = 6 
 
yes 
| ?- total_xor([5, 1, 6], Total). 
 
Total = 28 
 
yes 
| ?- total_xor([3, 4, 5, 6, 7, 8], Total). 
 
Total = 480 
 
yes 
| ?-

References

The Weekly Challenge 324
Generated Code

posted at: 14:40 by: Adam Russell | path: /prolog | permanent link to this entry